/*
	Title: Global Regular Expression Match
	
	Performs a global regular expression match.
	
	Function: RegExMatchAll
	
	Parameters:
		h - Haystack
		n - NeedleRegEx
		v - QuotedOutputVar
		p - StartingPosition (default: 1)
		s - PositionSuffix (default: "#")
		x - Limit - (default: 250)
	
	Notes:
		Subpatterns are created as OutputVar[x][y] where x is the main index
		and y is a name (i.e. (?P<abc>)) or sub-index (base 1)
	
	Returns:
		The number of matches.
	
	Function: grep
	
	A much faster variant of <RegExMatchAll> which lacks support for named subpatterns.
	
	Parameters:
		h - Haystack
		n - NeedleRegEx
		v - UnquotedOutputVar
		p - Subpattern (default: 0)
		s - StartingPosition (default: 1)
		d - Delimiter (default: ",")
		z - MatchFromLast (default: true)
	
	Notes:
		*OutputVar* is set to the list of matches of the
		specified subpattern, where 0 is the entire pattern. 
	
	Returns:
		A list of match positions.
	
	About: License
		- Version 1.3 by Titan <http://www.autohotkey.net/~Titan/#regexmatchall>.
		- Licenced under GNU GPL <http://creativecommons.org/licenses/GPL/2.0/>.

*/

RegExMatchAll(h, n, v, p = 1, s = "", x = 250) {
	local c = 0, t, t1, b, b0, b1, i, f, j, a
	Loop
		If p := RegExMatch(n, "si)(?<!\\)\((?:\?P<(\w+)>)?.+?(?<!\\)\)", t, p)
			c++, b .= t1 . "#", p += StrLen(t)
		Else Break
	StringSplit, b, b, #
	p := 1, s .= Chr(!s * 35)
	Loop, %x%
		If (i := A_Index) and %v%[%i%]%s% := p := RegExMatch(h, n, f, p)
			, p += StrLen(f), %v%[%i%] := f
			Loop, %c%
				j := A_Index, a := v . "[" . i . "]["
					. (b := b%j% ? b%j% : j) . "]", %a% := f%b%
		Else Return, i - 1
}

grep(h, n, ByRef v, b = 0, s = 1, d = ",", z = true) {
	Loop
		If s := RegExMatch(h, n, c, s)
			p .= s . d, s += z ? StrLen(c) : 1, y .= (b ? c%b% : c) . d
		Else Return, SubStr(p, 1, -1), v := SubStr(y, 1, -1)
}