; pöhserFensterKiller.ahk / (c) 2008 derRaphael / zLib Lizenz Stil
; Schließ das pöhse Fenster!

#WinActivateForce       ; Krieg das Fenster - egal wie
SetBatchLines, -1       ; Mach das Skript schneller
SetTitleMatchMode, 2    ; Mir langen nur ein paar Daten ...
DetectHiddenWindows, On ; Ich kriege Euch ALLE!!!
pöhserTitel := "James"
pöhseClassNN := "SunAwtFrame"
HilfeAnzeigen := "ja"

Menu, Tray, Icon, Shell32.dll, 77  ; zeig n lustiges bild

If (HilfeAnzeigen="ja") {
   Gosub, help
}
return

+^F1::
help:
  MsgBox,68,Information, % "Zur Benutzung:`n`n"
                   . "SHIFT+STRG+Q: Neues Pöhses Fenster wählen`n"
                   . "SHIFT+STRG+W: Auf Pöhses Fenster achten an/aus`n`n"
                   . "SHIFT+STRG+F1: Diese Hilfe anzeigen`n"
                   . "SHIFT+STRG+F10: Programm editieren`n"
                   . "SHIFT+STRG+F11: Programm beenden`n"
                   . "SHIFT+STRG+F12: Programm neu laden`n`n"
                   . "Soll die Hilfe beim Nächsten Start angezeigt werden?`n"
  IfMsgBox, Yes
    VarToApp("HilfeAnzeigen","ja")
  else
    VarToApp("HilfeAnzeigen","nein")
return

+^q::
  MsgBox,64,Hinweis, % "Such das Dich nervende pöhse Fenster`,`n"
                     . "halte die STRG-Taste und Klick es mit der Maus an`n"
                     . "`n"
                     . "Es wird dich nie wieder ärgern!"
  Hotkey, ^LButton, NeuesPöhsesFenster, ON
  SetTimer, hinweisAN, 50
return

+^w::
machDenModus:
if !(mEWZ)
{
  Menu, Tray, Icon, Shell32.dll, 66  ; zeig n anderes bild
  SetTimer, machEsWiederZu, 10       ; starte entdecker function
  mEWZ=1                             ; merke, was du getan hast
}
 else
{
  Menu, Tray, Icon, Shell32.dll, 77 
  SetTimer, machEsWiederZu, OFF
  mEWZ=0
}
return

+^f12::reload
+^f11::exitApp
+^f10::edit

machEsWiederZu:
   IfWinExist, %pöhserTitel% ahk_class %pöhseClassNN%
   {                                 ; existiert das pöhse Fenster?
                                     ; Zeig her das Ding
      WinActivate, %pöhserTitel% ahk_class %pöhseClassNN%
      WinWaitActive                  ; Warte du nur ....
      WinClose                       ; und weg is!
   }
return

NeuesPöhsesFenster:
  Hotkey, ^LButton, NeuesPöhsesFenster, OFF
  MouseGetPos,,, HWND                ; Zeig mir das pöhse Fenster!
  WinGetClass, neuePöhseClassNN, ahk_id %HWND%   ; Merke Dir die ClassNN
  WinGetTitle, neuerPöhserTitel , ahk_id %HWND%   ; Merke Dir den Titel
  MsgBox,64,Hab keine Furcht!, % "Ich habe das neue pöhse Fenster erkannt!`n`n"
                             . "Es hat folgende ClassNN:`n"
                             . """" NeuePöhseClassNN """`n"
                             . "und trägt folgenden Titel:`n"
                             . """" NeuerPöhserTitel """`n`n"
                             . "DAS merke ich mir! "
  VarToApp("pöhserTitel" ,neuerPöhserTitel)
  VarToApp("pöhseClassNN",neuePöhseClassNN)
  Gosub, hinweisAUS
  Gosub, machEsWiederZu
  If !(mEWZ) {
    Gosub, machDenModus
  }
return

hinweisAN:
  ToolTip, Klick das PÖHSE Fenster.
return

hinweisAUS:
  SetTimer, hinweisAN, OFF
  ToolTip
return

VarToApp( var,value ){               ; Hilfsfunktion, um neue Werte im Skript 
  NewVar := var " := """ value """"  ; dauerhaft zu Speichern
  Needle := var " := """ %var% """"
  %var% := value
  thisFile := A_ScriptFullPath
  FileRead, thisScript, %thisFile%
  StringReplace, thisScript, thisScript, %Needle%, %NewVar%
  If ( FileExist( thisFile ) ) {
     FileDelete, %thisFile%
  }
  FileAppend, %thisScript%, %thisFile%
}