; AHK BBCodeWriter - An offline BBCode editor
; Copyright (C) 2006  AGermanUser
;
; This program is free software; you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation; either version 2 of the License, or
; (at your option) any later version.
; 
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
; GNU General Public License for more details.
; 
; You should have received a copy of the GNU General Public License
; along with this program; if not, write to the Free Software
; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

CreatePreview:
  ; Initialise MaxCodeTags variable to reset previous code findings
  MaxCodeTags = 0

  ; Add signature if CheckBox is checked
  If ChkSig = 1
    {
      If DDLSig is not space
        {
          FileRead, SigText, %A_ScriptDir%\signatures\%DDLSig%
          bbcode = %bbcode%`n%SigText%
        }
    }

  ; Convert HTML sensitive chars ###############################################
  StringReplace, bbcode, bbcode, &, &amp`;, All
  StringReplace, bbcode, bbcode, <, &lt`;, All
  StringReplace, bbcode, bbcode, >, &gt`;, All

  ; Save content of all [code] Tags ############################################
  
  ; Find positions of all [code] Tags und save their position
  Loop,
    {
      StringGetPos, Position, bbcode, [code], L%A_Index%     
      If (ErrorLevel = 0)
        {
          CodeStartPos%A_Index% = %Position%
          MaxCodeTags = %A_Index%
          Continue
        }
      Else
        Break
    }
  
  ; Find positions of all [/code] Tags und save their position
  Loop,
    {
      StringGetPos, Position, bbcode, [/code], L%A_Index%      
      If (ErrorLevel = 0)
        {
          CodeEndPos%A_Index% = %Position%
          Continue
        }
      Else
        Break
    }

  ; Save content of [code] Tags
  Loop, %MaxCodeTags%
    {
      NumberOfCodeCharsToCopy := CodeEndPos%A_Index% - CodeStartPos%A_Index% - 6
      StringMid, CodeTag%A_Index%, bbcode, CodeStartPos%A_Index%+7, NumberOfCodeCharsToCopy
      
      ; Replace Space chars with &nbsp;
      StringReplace, CodeTag%A_Index%, CodeTag%A_Index%, % A_Space, &nbsp;, All
    }
  
  ; Convert Bold formatting ####################################################
  StringReplace, bbcode, bbcode, [b], <span style="font-weight: bold">, All
  StringReplace, bbcode, bbcode, [/b], </span>, All
  
  ; Convert Italic formatting ##################################################
  StringReplace, bbcode, bbcode, [i], <span style="font-style: italic">, All
  StringReplace, bbcode, bbcode, [/i], </span>, All
  
  ; Convert Underline formatting ###############################################
  StringReplace, bbcode, bbcode, [u], <span style="text-decoration: underline">, All
  StringReplace, bbcode, bbcode, [/u], </span>, All

  ; Convert Image formatting ###################################################
  StringReplace, bbcode, bbcode, [img], <img src=", All
  StringReplace, bbcode, bbcode, [/img], " />, All
     
  ; Convert Quote formatting ###################################################
  
  ; Case 1: [quote]Text[/quote]
  StringReplace, bbcode, bbcode, [quote], <div class="small"><b>Quote:</b></div><div class="quote">, All
  
  ; Case 2: [quote="name"]Text[/quote]
  Loop, 
    {
      StringGetPos, QuoteStartPos, bbcode, [quote=
      If ErrorLevel = 0
        {
          StringGetPos, QuoteEndPos, bbcode, ], L1, QuoteStartPos
          NumberOfQuoteCharsToCopy := QuoteEndPos - QuoteStartPos + 1
          StringMid, QuoteWithTags, bbcode, QuoteStartPos+1, NumberOfQuoteCharsToCopy
          
          StringTrimLeft, QuoteWithoutTags, QuoteWithTags, 8
          StringTrimRight, QuoteWithoutTags, QuoteWithoutTags, 2
          
          StringReplace, bbcode, bbcode, % QuoteWithTags
          , <div class="small"><b>%QuoteWithoutTags% wrote:</b></div><div class="quote">, All
        }
      Else
        Break
    }
   
  StringReplace, bbcode, bbcode, [/quote], </div>, All
  
  ; Convert URL formatting #####################################################
  
  ; Case 1: [url]Domain[/url]
  Loop,
    {
      StringGetPos, URLStartPos, bbcode, [url]
      If ErrorLevel = 0
        {
          ; Retrieve complete '[url]domain[/url]' string and assign to URLWithTags variable
          StringGetPos, URLEndPos, bbcode, [/url], L1, URLStartPos
          NumberOfURLCharsToCopy := URLEndPos - URLStartPos + 6
          StringMid, URLWithTags, bbcode, URLStartPos+1, NumberOfURLCharsToCopy
          
          ; Remove [url] and [/url] tags from left and right side of string
          StringTrimLeft, URLWithoutTags, URLWithTags, 5
          StringTrimRight, URLWithoutTags, URLWithoutTags, 6

          ; In case tags have been noted within [ur][/url] (e.g. [url][b]domain[/b][/url])
          ; leave [url] Tags untouched - not allowed
          TagsFound = 0
          Loop, Parse, URLWithoutTags
            {
              If A_LoopField = <
                TagsFound += 1
            }
          If TagsFound > 0
            {
              StringReplace, bbcode, bbcode, % URLWithTags, ~url]%URLWithoutTags%~/url]
              Continue                
            }
             
          ; Replace BBCode with HTML code
          StringReplace, bbcode, bbcode, % URLWithTags
          , <a href="%URLWithoutTags%" target="_blank" class="postlink">%URLWithoutTags%</a>
          Continue
        }
      Else
        Break
    }
  StringReplace, bbcode, bbcode, ~url], [url], All
  StringReplace, bbcode, bbcode, ~/url], [/url], All
  
  ; Case 2: [url=Domain]Linktext[/url]  
  Loop,
    {
      StringGetPos, URLStartPos, bbcode, [url=
      If ErrorLevel = 0
        {
          ; Make variables blank
          URLWithTags =
          URLWithoutTags =

          StringGetPos, URLEndPos, bbcode, [/url], L1, URLStartPos
          NumberOfURLCharsToCopy := URLEndPos - URLStartPos + 6                    
          StringMid, URLWithTags, bbcode, URLStartPos+1, NumberOfURLCharsToCopy

          StringSplit, ArrayOfURL, URLWithTags, ] ;, [url= [/url
          StringTrimLeft, ArrayOfURL1, ArrayOfURL1, 5
          StringTrimRight, ArrayOfURL2, ArrayOfURL2, 5

          StringReplace, bbcode, bbcode, % URLWithTags
          , <a href="%ArrayOfURL1%" target="_blank" class="postlink">%ArrayOfURL2%</a>
          Continue
        }
      Else
        Break
    }
  
  ; Convert E-Mail formatting ##################################################
  Loop,
    {
      StringGetPos, EmailStartPos, bbcode, [email]
      If ErrorLevel = 0
        {
          StringGetPos, EmailEndPos, bbcode, [/email]
          NumberOfEmailCharsToCopy := EmailEndPos - EmailStartPos + 8
          StringMid, EmailWithTags, bbcode, EmailStartPos+1, NumberOfEmailCharsToCopy
          
          StringSplit, ArrayOfEmail, EmailWithTags, ]
          StringTrimRight, ArrayOfEmail2, ArrayOfEmail2, 7
          
          StringReplace, bbcode, bbcode, % EmailWithTags
          , <a href="mailto:%ArrayOfEmail2%" class="postlink">%ArrayOfEmail2%</a>
          Continue
        }
      Else
        Break
    }
  
  ; Convert FontColor formatting ###############################################
  
  ; Case 1: [color="colorname"][/color]
  StringReplace, bbcode, bbcode, [color=darkred], <span style="color: darkred">, All
  StringReplace, bbcode, bbcode, [color=red], <span style="color: red">, All
  StringReplace, bbcode, bbcode, [color=orange], <span style="color: orange">, All
  StringReplace, bbcode, bbcode, [color=brown], <span style="color: brown">, All
  StringReplace, bbcode, bbcode, [color=yellow], <span style="color: yellow">, All
  StringReplace, bbcode, bbcode, [color=green], <span style="color: green">, All
  StringReplace, bbcode, bbcode, [color=olive], <span style="color: olive">, All
  StringReplace, bbcode, bbcode, [color=cyan], <span style="color: cyan">, All
  StringReplace, bbcode, bbcode, [color=blue], <span style="color: blue">, All
  StringReplace, bbcode, bbcode, [color=darkblue], <span style="color: darkblue">, All
  StringReplace, bbcode, bbcode, [color=indigo], <span style="color: indigo">, All
  StringReplace, bbcode, bbcode, [color=violet], <span style="color: violet">, All
  StringReplace, bbcode, bbcode, [color=white], <span style="color: white">, All
  StringReplace, bbcode, bbcode, [color=black], <span style="color: black">, All  

  ; Case 2: [color=#hexvalue][/color]
  Loop,
    {
      StringGetPos, ColorStartPos, bbcode, [color=
      If ErrorLevel = 0
        {
          StringGetPos, ColorEndPos, bbcode, ], L1, ColorStartPos
          NumberOfColorCharsToCopy := ColorEndPos - ColorStartPos + 1
          StringMid, ColorWithTags, bbcode, ColorStartPos+1, NumberOfColorCharsToCopy
          
          StringTrimLeft, ColorWithoutTags, ColorWithTags, 7
          StringTrimRight, ColorWithoutTags, ColorWithoutTags, 1
          
          StringReplace, bbcode, bbcode, % ColorWithTags, <span style="color:%ColorWithoutTags%">, All
        }
      Else
        Break
    }

  StringReplace, bbcode, bbcode, [/color], </span>, All

  ; Convert FontSize formatting ################################################
  Loop, %MaxFontSize%
    {
      StringReplace, bbcode, bbcode, [size=%A_Index%]
      , <span style="font-size: %A_Index%px; line-height: normal">, All
    }
  StringReplace, bbcode, bbcode, [/size], </span>, All

  ; Convert Numbered List formatting ###########################################
  NumListTag = <ol type="1">
  
  Loop, 
    {
      ; Position of List Tag
      StringGetPos, ListStartPos, bbcode, [list=1]
      If Errorlevel = 0
        {
          ; Position of first ending tag
          StringGetPos, ListEndPos, bbcode, [/list],, %ListStartPos%

          CountLists := ListStartPos + 1
          
          ; Counting variable for List Tag between first List Tag 
          ; and first ending List Tag
          i = 1
          
          Loop, 
            {
              ; Find position of next List Tag
              StringGetPos, NextListStart, bbcode, [list,, CountLists
              If ErrorLevel = 0
                {
                  ; If next List Tag is between first List Tag and first ending List Tag
                  If (NextListStart < ListEndPos)
                    {
                      i++
                      CountLists := ListStartPos + 1 + NextListStart
                      Continue
                    }
                  Else
                      Break               
                }
              Else                 
                Break
            }
          If i > 1
            StringGetPos, ListEndPos, bbcode, [/list], L%i%, %ListStartPos%
                                        
          bbcode := StringReplaceWord(bbcode, ListEndPos, 7, "</ol>")
          bbcode := StringReplaceWord(bbcode, ListStartPos, 8, NumListTag)
        }
      Else
        Break
    }

  ; Convert Alphabetical List formatting #######################################
  CharListTag = <ol type="a">
  
  Loop, 
    {
      ; Position of List Tag
      StringGetPos, ListStartPos, bbcode, [list=a]
      If Errorlevel = 0
        {
          ; Position of first ending tag
          StringGetPos, ListEndPos, bbcode, [/list],, %ListStartPos%
          
          CountLists := ListStartPos + 1
          
          ; Counting variable for List Tag between first List Tag 
          ; and first ending List Tag
          i = 1
          
          Loop, 
            {
              ; Find position of next List Tag
              StringGetPos, NextListStart, bbcode, [list,, CountLists
              If ErrorLevel = 0
                {
                  ; If next List Tag is between first List Tag and first ending List Tag
                  If (NextListStart < ListEndPos)
                    {
                      i++
                      CountLists := ListStartPos + 1 + NextListStart
                      Continue
                    }
                  Else
                      Break               
                }
              Else                 
                Break
            }
          StringGetPos, ListEndPos, bbcode, [/list], L%i%, %ListStartPos% 
          bbcode := StringReplaceWord(bbcode, ListEndPos, 7, "</ol>")
          bbcode := StringReplaceWord(bbcode, ListStartPos, 8, CharListTag)
        }
      Else
        Break
    }

  ; Convert Unordered List formatting ##########################################
  Loop, 
    {
      ; Position of List Tag
      StringGetPos, ListStartPos, bbcode, [list]
      If Errorlevel = 0
        {
          ; Position of first ending tag
          StringGetPos, ListEndPos, bbcode, [/list],, %ListStartPos%

          CountLists := ListStartPos + 1
          
          ; Counting variable for List Tag between first List Tag 
          ; and first ending List Tag
          i = 1
          
          Loop, 
            {
              ; Find position of next List Tag
              StringGetPos, NextListStart, bbcode, [list,, CountLists
              
              If ErrorLevel = 0 
                {
                  
                  ; If next List Tag is between first List Tag and first ending List Tag
                  If (NextListStart < ListEndPos)
                    {
                      i++
                      CountLists := ListStartPos + 1 + NextListStart
                      Continue
                    }
                  Else
                      Break               
                }
              Else                 
                Break
            }
          StringGetPos, ListEndPos, bbcode, [/list], L%i%, %ListStartPos%
          bbcode := StringReplaceWord(bbcode, ListEndPos, 7, "</ul>")
          bbcode := StringReplaceWord(bbcode, ListStartPos, 6, "<ul>")
        }
      Else
        Break
    }

  ; Convert List Style Type formatting #########################################
  StringReplace, bbcode, bbcode, [*], <li>, All

  ; Convert Smileys  ########################################################### 
  StringReplace, bbcode, bbcode, :arrow:, <img src="phpbb/smileys/icon_arrow.gif" alt="Arrow" />, All
  StringReplace, bbcode, bbcode, :idea:, <img src="phpbb/smileys/icon_idea.gif" alt="Idea" />, All
  StringReplace, bbcode, bbcode, :wink:, <img src="phpbb/smileys/icon_wink.gif" alt="Wink" />, All
  StringReplace, bbcode, bbcode, :cry:, <img src="phpbb/smileys/icon_cry.gif" alt="Cry" />, All
  StringReplace, bbcode, bbcode, :evil:, <img src="phpbb/smileys/icon_evil.gif" alt="Evil" />, All
  StringReplace, bbcode, bbcode, :twisted:, <img src="phpbb/smileys/icon_twisted.gif" alt="Twisted" />, All
  StringReplace, bbcode, bbcode, :roll:, <img src="phpbb/smileys/icon_rolleyes.gif" alt="RollEyes" />, All
  StringReplace, bbcode, bbcode, :lol:, <img src="phpbb/smileys/icon_lol.gif" alt="Lol" />, All
  StringReplace, bbcode, bbcode, :oops:, <img src="phpbb/smileys/icon_redface.gif" alt="Razz" />, All
  StringReplace, bbcode, bbcode, :shock:, <img src="phpbb/smileys/icon_eek.gif" alt="Shocked" />, All
  StringReplace, bbcode, bbcode, :mrgreen:, <img src="phpbb/smileys/icon_mrgreen.gif" alt="MrGreen" />, All
  StringReplace, bbcode, bbcode, :?:, <img src="phpbb/smileys/icon_question.gif" alt="Question Mark" />, All
  StringReplace, bbcode, bbcode, :!:, <img src="phpbb/smileys/icon_exclaim.gif" alt="Exclamation Mark" />, All
  StringReplace, bbcode, bbcode, :D, <img src="phpbb/smileys/icon_biggrin.gif" alt="Big Grin" />, All
  StringReplace, bbcode, bbcode, :), <img src="phpbb/smileys/icon_smile.gif" alt="Smile" />, All
  StringReplace, bbcode, bbcode, :(, <img src="phpbb/smileys/icon_sad.gif" alt="Sad" />, All
  StringReplace, bbcode, bbcode, :o, <img src="phpbb/smileys/icon_surprised.gif" alt="Surprised" />, All
  StringReplace, bbcode, bbcode, :?, <img src="phpbb/smileys/icon_confused.gif" alt="Confused" />, All
  StringReplace, bbcode, bbcode, 8), <img src="phpbb/smileys/icon_cool.gif" alt="Cool" />, All
  StringReplace, bbcode, bbcode, :x, <img src="phpbb/smileys/icon_mad.gif" alt="Mad" />, All
  StringReplace, bbcode, bbcode, :P, <img src="phpbb/smileys/icon_razz.gif" alt="Razz" />, All
  StringReplace, bbcode, bbcode, `;), <img src="phpbb/smileys/icon_wink.gif" alt="Wink" />, All
  StringReplace, bbcode, bbcode, :|, <img src="phpbb/smileys/icon_neutral.gif" alt="Neutral" />, All
  
  ; Convert Code Tags formatting ###############################################

  ; Find positions of all accidentally formatted [code] Tags und save their positions
  Loop,
    {
      StringGetPos, Position, bbcode, [code], L%A_Index%      
      If (ErrorLevel = 0)
        {
          CodeStartPos%A_Index% = %Position%
          MaxCodeTags = %A_Index%
          Continue
        }
      Else
        Break
    }

  ; Find positions of all accidentally formatted [/code] Tags und save their positions
  Loop, %MaxCodeTags%
    {
      StringGetPos, Position, bbcode, [/code], L%A_Index%      
      If (ErrorLevel = 0)
        {
          CodeEndPos%A_Index% = %Position%
          Continue
        }
      Else
        Break
    }

  ; Find content of formatted [code] Tags and replace them with the original code
  Loop, %MaxCodeTags%
    {
      GoSub, FindCodePositions
      NumberOfCodeCharsToCopy := CodeEndPos%A_Index% - CodeStartPos%A_Index% - 6
      StringMid, ChangedCodeTag%A_Index%, bbcode, CodeStartPos%A_Index%+7, NumberOfCodeCharsToCopy
      StringReplace, bbcode, bbcode, % ChangedCodeTag%A_Index%, % CodeTag%A_Index%
    }
  
  StringReplace, bbcode, bbcode, [code], <div class="small"><b>Code:</b></div><div class="code">, All
  StringReplace, bbcode, bbcode, [/code], </div>, All
  
  ; Convert Linebreaks #########################################################
  StringReplace, bbcode, bbcode, `n, <br>`n, All

 
  ; Create Head of HTML page
  FileAppend,
    (LTrim
      <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">
      <html>
        <head>
          <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
          <link rel="stylesheet" type="text/css" href="./phpbb/style.css" />
        
          <title>BBCodeWriter Preview</title>
        </head>
      
      <body>
        <div id="head">
          <img id="logo" src="phpbb/images/logo.gif" alt="" />
          <span id="title">version %Version%</span>            
        </div>
      
        <div id="postbody">
          <p id="postheader">Message</p>
          <div id="posttext">
    ), preview.html

  ; Paste postingtext in HTML page
  FileAppend, %bbcode%, preview.html

  ; Create end of HTML page
  FileAppend,
    (LTrim
        </div>
      </div>
    </body>
    
    </html>  
    ), preview.html

  ; Check whether BBCodeWriter already created a browser window
  IfWinExist, BBCodeWriter Preview
    {
      WinActivate, BBCodeWriter Preview
      Send, {F5}
    } 
  Else
    {
      ; Run defined browser with preview page
      Run, %BrowserExe% "%A_WorkingDir%\preview.html" 
      WinWait, BBCodeWriter Preview
      WinActivate, BBCodeWriter Preview   
    }
Return


;##############################################################################
;####### General Subroutines ##################################################
;##############################################################################
FindCodePositions:
  ; Find positions of all accidentally formatted [code] Tags und save their positions
  Loop,
    {
      StringGetPos, Position, bbcode, [code], L%A_Index%      
      If (ErrorLevel = 0)
        {
          CodeStartPos%A_Index% = %Position%
          MaxCodeTags = %A_Index%
          Continue
        }
      Else
        Break
    }

  ; Find positions of all accidentally formatted [/code] Tags und save their positions
  Loop, %MaxCodeTags%
    {
      StringGetPos, Position, bbcode, [/code], L%A_Index%      
      If (ErrorLevel = 0)
        {
          CodeEndPos%A_Index% = %Position%
          Continue
        }
      Else
        Break
    }
Return
;##############################################################################
;####### End of General Subroutines ###########################################
;##############################################################################